Ini文件精解示例

icecept · 发表于 2008-12-17 08:45:02

本帖最后由 icecept 于 2016-11-2 17:02 编辑

'**************************************************************************
'**模块名：INI 文件操作 - 操作ini.bas
'**说明：
'**创建人：icecept(郭卫)
'**日期：2008-12-15 00:11:06
'**修改人：icecept(魔灵)
'**日期：2009-1-9 01:20:23
'**描述：icecept(魔灵)制作
'**版本：V1.0.0 http://blog.sina.com.cn/icecept
'*************************************************************************
Option Explicit
'读出自定义INI文件
Private Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
'写入自定义INI文件
Public Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long
'读出自定义INI文件中的单个区段间的所有键名和值
Public Declare Function GetPrivateProfileSection Lib "kernel32" Alias "GetPrivateProfileSectionA" (ByVal lpAppName As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
'读出自定义INI所有区段名
Public Declare Function GetPrivateProfileSectionNames Lib "kernel32.dll" Alias "GetPrivateProfileSectionNamesA" (ByVal lpszReturnBuffer As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
'*************************************************************************
'**函数名：GetIni
'**功能描述：从自定义ini文件中读信息 SectionName:区段名 KeyWord:具体键名 DefString:读取失败后返回默认 FileName:ini文件所在路径
'**补充：读出的都是String类型的,如果你想读数字型的,可用VB的val()函数将其转化
'*************************************************************************
Public Function GetIni(ByVal SectionName As String, ByVal KeyWord As String, ByVal DefString As String, ByVal FileName As String) As String
Dim ResultString As String * 255
If GetPrivateProfileString(ByVal SectionName, ByVal KeyWord, vbNullString, ByVal ResultString, ByVal Len(ResultString), ByVal FileName) > 0 Then '关键词的值不为空
GetIni = Left(ResultString, InStr(ResultString, Chr(0)) - 1)
Else '将缺省值写入INI文件
WritePrivateProfileString SectionName, KeyWord, DefString, FileName
GetIni = DefString
End If
End Function
'*************************************************************************
'**函数名：GetKeyWord
'**功能描述：从自定义ini文件中得到键名和值
'** SectionName:区段名 DefString:默认值 FileName:ini文件所在路径
'**补充：?
'*************************************************************************
Public Function GetKeyWord(ByVal SectionName As String, ByVal DefString As String, ByVal FileName As String) As String
Dim szBuf As String * 255
If GetPrivateProfileSection(ByVal SectionName, ByVal szBuf, Len(szBuf), ByVal FileName) > 0 Then
'同时获取键名和值
GetKeyWord = Left(szBuf, InStr(szBuf, Chr(0)) - 1)
Else
WritePrivateProfileString SectionName, DefString, vbNullString, FileName
GetKeyWord = DefString
End If
End Function
'*************************************************************************
'**函数名：GetKey
'**功能描述：从自定义ini文件中得到键名
'** SectionName:区段名 DefString:默认值 FileName:ini文件所在路径
'**补充：?
'*************************************************************************
Public Function GetKey(ByVal SectionName As String, ByVal DefString As String, ByVal FileName As String) As String
Dim szBuf As String * 255, ResultString As String
ResultString = GetKeyWord(ByVal SectionName, ByVal szBuf, ByVal FileName)
If InStr(ResultString, "=") <> 0 Then
GetKey = Left(ResultString, InStr(ResultString, "=") - 1)
Else
GetKey = DefString
End If
End Function
'**************************************************************************
'**模块名：INI 文件操作 - frmINI
'**说明：
'**创建人：icecept(魔灵)
'**日期：2008-12-15 00:44:23
'**修改人：icecept(魔灵)
'**日期：2009-1-9 01:20:23
'**描述：icecept(魔灵)制作
'**版本：V1.0.0 http://blog.sina.com.cn/icecept
'*************************************************************************
Option Explicit
'读取 test.ini　文件的值
Private Sub Command1_Click()
On Error Resume Next
Dim Ret1 As String, Ret2 As String
Dim Key1 As String, Key2 As String
Dim SectionArr() As String, m As Integer, Length As Integer
Dim szBuf As String * 255
'得到值区段名，键名，读取失败时的默认值，文件名
Ret1 = GetIni("a", "b", vbNullString, App.Path & "\test.ini")
Ret2 = GetIni("d", "e", vbNullString, App.Path & "\test.ini")
'得到建名区段名，键名，文件名
Key1 = GetKey("a", szBuf, App.Path & "\test.ini")
Key2 = GetKey("d", szBuf, App.Path & "\test.ini")
'得到区段名　　　　　　　　　　区段名　，键名，　文件名
Length = GetPrivateProfileSectionNames(szBuf, Len(szBuf), App.Path & "\test.ini")
szBuf = Left(szBuf, Length)
SectionArr = Split(szBuf, vbNullChar)
'如果数组为空，说明ini文件是空文件，直接退出
If UBound(SectionArr) > 0 Then
If Len(Key1) = 255 Then
MsgBox "[" & Split(szBuf, vbNullChar)(0) & "]" & vbCrLf & "[" & Trim(Split(szBuf, vbNullChar)(1)) & "]" & "=" & Ret2
Else
MsgBox "[" & Split(szBuf, vbNullChar)(0) & "]" & vbCrLf & Key1 & "=" & Ret1 & vbCrLf & "[" & Trim(Split(szBuf, vbNullChar)(1)) & "]" & vbCrLf & Key2 & "=" & Ret2
End If
Else
MsgBox "ini文件是空的"
End If
End Sub
Private Sub Command10_Click()
'获取win.ini所有区段名
List1.Clear
Dim szBuf As String, Length As Integer
Dim SectionArr() As String, m As Integer
szBuf = String$(255, 0)
Length = GetPrivateProfileSectionNames(szBuf, Len(szBuf), "c:\windows\win.ini")
szBuf = Left(szBuf, Length)
SectionArr = Split(szBuf, vbNullChar)
For m = 0 To UBound(SectionArr)
List1.AddItem SectionArr(m)
Next m
End Sub
Private Sub Command11_Click()
'获取win.in某区段内所有键名和值的列表
List1.Clear
Dim Length As Integer
Dim SectionArr() As String, m As Integer
Dim szBuf As String * 255
Length = GetPrivateProfileSection("rBnwares", szBuf, Len(szBuf), "c:\windows\win.ini")
szBuf = Left(szBuf, Length)
SectionArr = Split(szBuf, vbNullChar)
For m = 0 To UBound(SectionArr)
List1.AddItem SectionArr(m)
Next m
End Sub
Private Sub Command12_Click()
' 区段名，键名，值，文件名
WritePrivateProfileString "a", "b", "c", App.Path & "\test.ini"
WritePrivateProfileString "d", "e", "f", App.Path & "\test.ini"
End Sub
Private Sub Command2_Click()
'修改键值
Dim AA As String
AA = InputBox("请输入新的a区段键名b下的值", Me.Caption)
If AA <> vbNullString Then
WritePrivateProfileString "a", "b", AA, App.Path & "\test.ini"
MsgBox "修改成功"
End If
End Sub
Private Sub Command3_Click()
'删除a区段下的一个键名,删除键名后，键名下的值也会同时删除
' 区段名键名
WritePrivateProfileString "a", "b", vbNullString, App.Path & "\test.ini"
End Sub
Private Sub Command4_Click()
'删除整个区段,,删除区段后，区段下的键名和值也会同时删除
' 区段名
WritePrivateProfileString "a", vbNullString, vbNullString, App.Path & "\test.ini"
WritePrivateProfileString "d", vbNullString, vbNullString, App.Path & "\test.ini"
End Sub
Private Sub Command5_Click()
'在win.ini中写入键值
Dim AA As String
AA = InputBox("请输入新值", Me.Caption)
If AA <> vbNullString Then
WritePrivateProfileString "rBnwares", "Year", AA, "c:\windows\win.ini"
WritePrivateProfileString "rBnwares", "Month", AA, "c:\windows\win.ini"
WritePrivateProfileString "rBnwares", "Day", AA, "c:\windows\win.ini"
MsgBox "修改成功"
End If
End Sub
Private Sub Command6_Click()
'读取数据区段名键名默认值文件名
MsgBox GetIni("rBnwares", "Year", vbNullString, "c:\windows\win.ini")
End Sub
Private Sub Command7_Click()
'删除整个区段,,删除区段后，区段下的键名和值也会同时删除
' 区段名，文件名
WritePrivateProfileString "rBnwares", vbNullString, vbNullString, "c:\windows\win.ini"
End Sub
Private Sub Command8_Click()
'获取键名
Dim szBuf As String * 255
' 区段名，键名，文件名
MsgBox GetKeyWord("rBnwares", szBuf, "c:\windows\win.ini")
End Sub
Private Sub Command9_Click()
'获取键名
Dim szBuf As String * 255
' 区段名，键名，文件名
MsgBox GetKey("rBnwares", szBuf, "c:\windows\win.ini")
End Sub
'写入 test.ini　文件的值
Private Sub Form_Load()
End Sub
'生成的test.ini 文件格式:
'
'[a] a: 区段名
'b=c　　　　　b：键名 c：值
'[d] d: 区段名
'e=f e：键名 f：值
'--------------------------------------------------------------------------------------
'操作ini文件的函数列表:
'只能操作win.ini的函数
'WriteProfileString 在win.ini初始化文件指定小节内设置一个字串
'WriteProfileSection 为win.ini初始化文件中一个指定的小节设置所有项名和值
'GetProfileInt 取得win.ini初始化文件中指定条目的一个整数值
'GetProfileSection 获取指定小节（在win.ini文件中）所有项名和值的一个列表
'GetProfileString 为win.ini初始化文件中指定的条目取得字串
'======================================================================================
'即能操作win.ini的函数，又能操作自定义ini文件的函数
'WritePrivateProfileString 在初始化文件指定小节内设置一个字串
'WritePrivateProfileSection 为一个初始化文件（.ini）中指定的小节设置所有项名和值
'GetPrivateProfileInt 为初始化文件中指定的条目获取一个整数值
'GetPrivateProfileSection 获取指定小节所有项名和值的一个列表
'GetPrivateProfileString 为初始化文件中指定的条目取得字串
'GetPrivateProfileSectionNames 读出INI文件中所有区段名

复制代码

[ 本帖最后由 icecept 于 2009-1-11 21:03 编辑 ]

icecept · 发表于 2008-12-17 08:48:09

一、INI文件概述
　　Windows INI文件,可解释为Windows初始化文件。它是一种专门用来保存应用程序初始化信息和运行环境信息的文本文件。例如Windows 3.1中两个著名的INI文件win.ini和system.ini就在Windows启动时定义了Windows环境中鼠标响应速度、使用的外壳(shell)程序等设置。Windows系统附带的许多应用程序也都有自己的INI文件,例如控制面板的INI 文件为control.ini,它也同样定义了控制面板的有关设置。ini文件是一种文本文件,它可以通过Notepad等文本编辑器进行编辑。ini文件具有特定的格式。一个INI文件是由若干个段(section)组成的,每个段中包含若干关键字(key)及相应的值(value)。段的格式如下:
[SectionName]
KeyName=Value
其中SectionName和KeyName分别是段名和关键字名,Value为关键字对应的设定值。需要加以注意的是:
(1)段名必须加以"["和"]",且"["必须在屏幕的第一列;
(2)关键字名也必须从屏幕的第一列开始书写,且后面必须紧跟"=";
(3)可以对文件加以注释,每行注释须以";"开头。
　　在Windows中,可以通过手工编辑INI 文件来改变应用程序设置。如要想将Windows的外壳程序改为文件管理器,则可将system.ini中[boot]段下的"shell=progman.exe"改为"shell=winfile.exe"。有些设置也可以直接在应用程序界面上更改,但实际上也是通过修改INI文件来保存这些修改的。
二、在VB中操作INI文件的几个Windows API函数
　　在开发应用程序时,我们可以创建应用程序自己的INI文件,通过INI文件保存应用程序的一些运行环境信息,然后在程序中读取INI文件中的设置信息并据以处理。一旦程序的运行环境需要变更,则可以通过直接修改INI文件或在程序中提供专门的界面间接地修改INI文件来保证程序的可用性。
　　VB(Visual Basic)语言是近年来十分流行的一种面向对象的编程语言,但VB本身并不提供操纵INI文件的函数。所幸的是, VB支持DLL(Dynamic Link Library)的调用。(一个DLL事实上就是一个可供其它支持DLL调用的应用程序调用的外部函数集。)DLL中的函数称为API(应用编程接口,Application Programming Interface)函数。我们可以通过调用相应的API函数来实现操纵INI文件的功能。下面列出了相关的API函数及其说明。在使用这些函数之前,必须首先在VB的模块文件(.bas)中用Declare语句对它们进行声明。
三、实例分析
　　下面就笔者参加天津财经学院教学办公自动化(OA)系统开发的实践介绍一下具体的实现方法。假定项目文件为man.mak,对应的INI文件为man.ini,其部分内容如下:
[数据库]
文件名=\\DEC_LX5120\DB\OA.mdb
[开户银行]
类型数=3
B1=中国人民银行
B2=中国农业银行
B3=中国工商银行
1. 在程序启动时(执行SUB MAIN()和SUB FORM_LOAD()),从man.ini文件中读取相应的值并进行以后的操作。其中SUB MAIN()中的有关代码如下:
Dim DbName as String*255 '数据库名
Dim n as Integer
'得到INI文件名,INIfileName为一全局变量
INIfileName=App.Path&""&app.ExeName&".ini"
'从man.ini中读取数据库文件名
n=GetPrivateProfileString("数据库","文件名","",DbName,Len(DbName),INIfileName)
DbName=Left(DbName,n)
'打开数据库,Db为一全局变量
Set Db=OpenDatabase(DbName)
在FORM_LOAD()过程中,读取了man.ini中有关的内容并加入相应的组合框(Combo Box)列表中。这里只给出对"[开户银行]"段的相应操作,代码如下:
Dim BankCount as Integer '银行类型数
Dim BankName as String*255 '银行名
Dim i as Integer,n as Integer
'读取原有银行类型数
BankCount=GetPrivateProfileInt("开户银行","类型数",0,INIfileName)
'读取银行名并加入到组合框cmbBank中
For I=1 to BankCount
n=GetPrivateProfileString("开户银行","B"&i,BankName,Len(BankName),INIfileName)
BankName=Left(BankName,n)
cmbBank.AddItem BankName
Next I
2. 在程序中提供了一个专用维护界面,该界面通过操作INI文件的相应内容来实现相应的修改。
'下面代码实现数据库路径的修改
Dim n as Integer
'txtDbName.Text对应新的数据库文件名
If txtDbName.Text="" Then
MsgBox "数据库文件名不能为空!",MB_ICONSTOP,App.Title
txtDbName.SetFocus
Exit Sub
Else
'修改数据库文件名
n=WritePrivateProfileString("数据库","文件名",txtDbName.Text,INIfileName)
End If
'下面代码往组合框"开户银行"中增加一个新银行
Dim NewBank as String '新银行名
Dim BankCount as Integer '银行类型数
Dim I as Integer,n as Integer
'输入新银行名
NewBank=InputBox("增加开户银行。",App.Title,"")
If NewBank="" Then
MsgBox "银行名不能为空!",MB_ICONSTOP,App.Title
Exit Sub
Else
'判断输入的银行名是否已存在于列表中
For I=0 to cmbBank.ListCount-1
If NewBank=cmbBank.List(i) Then
'存在则终止
MsgBox NewBank&"已存在于列表中!",MB_ICONSTOP,App.Title)
Exit Sub
End If
Next I
'读取原银行类型数
BankCount=GetPriVateProfileInt("开户银行","类型数",0,INIfileName)
'将银行类型数增1
BankCount=BankCount+1
n=WritePrivateProfileString("开户银行","类型数",Str(BankCount),INIfileName)
'将新银行名写入INI文件中
n=WritePrivateProfileString("开户银行","B"&BankCount,NewBank,INIfileName)
End If
四、结论
　　综上所述,在实际的VB应用程序开发中,适当地利用INI文件,可以很好地改善程序的可维护性和可用性。尤其在数据库访问中使用INI文件可使用户在数据库路径改变时免去修改原代码之苦。在实际开发中,若结合一定的维护界面,也可使应用程序容易维护,增强友好性。

复制代码

[ 本帖最后由 icecept 于 2009-1-11 21:05 编辑 ]

wajika · 发表于 2008-12-22 19:32:20

文章的不错，收藏了

icecept · 发表于 2008-12-28 17:43:32

[ 本帖最后由 icecept 于 2008-12-28 18:10 编辑 ]

icecept · 发表于 2009-1-3 20:49:39

'**************************************************************************
'**模块名：INI 文件操作 - frmINI
'**说明：
'**创建人：icecept(魔灵)
'**日期：2008-12-15 00:44:23
'**修改人：icecept(魔灵)
'**日期：
'**描述：icecept(魔灵)制作
'**版本：V1.0.0 http://icecept.blog.sohu.com
'*************************************************************************
Option Explicit
'读出自定义INI文件中的单个区段间的所有键名和值
Private Declare Function GetPrivateProfileSection Lib "kernel32" Alias "GetPrivateProfileSectionA" (ByVal lpAppName As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
Private Sub Command1_Click()
'获取某区段内所有键名和值的列表
List1.Clear
Dim Length As Integer
Dim SectionArr() As String, m As Integer
Dim szBuf As String * 255
Length = GetPrivateProfileSection("icecept", szBuf, Len(szBuf), App.Path & "\test.ini")
szBuf = Left(szBuf, Length)
SectionArr = Split(szBuf, vbNullChar)
For m = 0 To UBound(SectionArr)
List1.AddItem SectionArr(m)
Next m
End Sub

获取ini一个区段内所有值的列表.rar

icecept · 发表于 2009-1-4 13:10:54

本帖最后由 icecept 于 2016-11-2 17:04 编辑

'**************************************************************************
'**模块名：INI 文件操作 - frmINI
'**说明：删除ini文件一个区段或特定某行的值
'**创建人：icecept(郭卫)
'**日期：2009-01-03 12:55:20
'**修改人：郭卫(魔灵)
'**日期：
'**描述：icecept(魔灵)制作
'**版本：V1.0.0 http://blog.sina.com.cn/icecept
'*************************************************************************
Option Explicit
'读出自定义INI文件
Private Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
'写入自定义INI文件
Private Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long

Private Sub Command3_Click()
'删除icecept区段下的一个键名icecept,删除键名后，键名下的值也会同时删除
'          区段名键名
   WritePrivateProfileString "icecept", "icecept", vbNullString, App.Path & "\test.ini"
End Sub

Private Sub Command2_Click()
'删除整个区段,,删除区段后，区段下的键名和值也会同时删除
'                         区段名
   WritePrivateProfileString "icecept", vbNullString, vbNullString, App.Path & "\test.ini"
End Sub

Private Sub Command1_Click()
' 区段名，键名，值，文件名
   WritePrivateProfileString "icecept", "VB", "vbgood", App.Path & "\test.ini"
   WritePrivateProfileString "icecept", "FOX", "FoxPro", App.Path & "\test.ini"
   WritePrivateProfileString "icecept", "C", "C++", App.Path & "\test.ini"
   WritePrivateProfileString "icecept", "icecept", "魔灵", App.Path & "\test.ini"
End Sub

'写入 test.ini　文件的值
Private Sub Form_Load()
   Command1.Value = True
End Sub

附件: 删除ini一个区段或特定某行的值.rar

图片附件: 1.jpg

图片附件: 2.jpg

[ 本帖最后由 icecept 于 2009-1-4 13:31 编辑 ]

icecept · 发表于 2009-1-9 12:10:17

本帖最后由 icecept 于 2016-11-2 17:04 编辑

'**************************************************************************
'**模块名：INI 文件操作 - 操作ini.bas
'**说明：
'**创建人：icecept(魔灵)
'**日期：2008-12-15 00:11:06
'**修改人：icecept(魔灵)
'**日期：2009-1-9 01:20:23
'**描述：icecept(魔灵)制作
'**版本：V1.0.0 http://blog.sina.com.cn/icecept
'*************************************************************************

Private Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
Dim b1 As String, b2 As String, b3 As String

Private Sub Form_Load()
Dim szBuf As String * 255

GetPrivateProfileString "main", "标题", vbNullString, szBuf, Len(szBuf), App.Path & "\test.ini"
b1 = Left(szBuf, InStr(szBuf, Chr(0)) - 1)

GetPrivateProfileString "main", "文件名", vbNullString, szBuf, Len(szBuf), App.Path & "\test.ini"
b2 = Left(szBuf, InStr(szBuf, Chr(0)) - 1)

GetPrivateProfileString "main", "大小", vbNullString, szBuf, Len(szBuf), App.Path & "\test.ini"
b3 = Left(szBuf, InStr(szBuf, Chr(0)) - 1)

MsgBox b1 & vbCrLf & b2 & vbCrLf & b3
End Sub

[ 本帖最后由 icecept 于 2009-1-9 23:19 编辑 ]

icecept · 发表于 2009-1-24 09:50:06

本帖最后由 icecept 于 2016-11-2 17:05 编辑

在文本框中显示ini文件中所对应的值

Option Explicit
'**************************************************************************
'**模块名：INI 文件操作 - 操作ini.bas
''**说明：魔灵圣域 by icecept(郭卫）
'**创建人：icecept(魔灵)
'**日期：2009-03-12 01:03:56
'**修改人：icecept(魔灵)
'**版本：V1.0.0
'**E-mail  ：icecept@163.com QQ：543375508
'**网址： http://blog.sina.com.cn/icecept
'*************************************************************************
Private Sub Command1_Click()
'获取键名
Dim szBuf As String * 255, Length As Integer
Length = GetPrivateProfileSectionNames(szBuf, Len(szBuf), App.Path & "\test.ini")
szBuf = Left(szBuf, Length)
Text1(0).Text = Split(szBuf, vbNullChar)(0)
'             区段名，键名，文件名
Text1(1).Text = GetKey(Text1(0).Text, szBuf, App.Path & "\test.ini")
'读取数据    区段名    键名    默认值          文件名
Text1(2).Text = GetIni(Text1(0).Text, Text1(1).Text, vbNullString, App.Path & "\test.ini")
End Sub
Private Sub Form_Load()
'    区段名，键名，值，文件名
WritePrivateProfileString "Command6", "4320", "1230", App.Path & "\test.ini"
End Sub

附件: 在文本框中显示ini文件中所对应的值.rar

[ 本帖最后由 icecept 于 2009-3-12 19:39 编辑 ]

nmwwf · 发表于 2009-3-2 16:09:34

好文章收藏

yanggo · 发表于 2009-8-5 15:30:13

不错，很详细。慢慢学习。

		自动登录	找回密码
密码			立即注册

VBGood网站全文搜索

[原创] Ini文件精解示例

评分

ＩＮＩ　文件详解（from　to　baidu)

评分

能读多行啊

获取ini一个区段内所有值的列表

删除ini文件一个区段或特定某行的值

分别得到一个区段内各键名下的值